No estoy seguro de si este es tu problema, pero setPinValues me parece extraño:

void setPinValues(String message) {
  for(int i = 1; i <= sizeof(pins) / sizeof(pins[0]); i++ ) {
    String pinNumber = String(i);

    if( message == pinNumber + "H\n" ) {
      pinValues[i] = HIGH;
    }
    if( message == pinNumber + "L\n" ) {
      pinValues[i] = LOW;
    }
  }
}

Salir fuera de límites

Cada vez que llame a setPinValues , i variará de 1 a length(pins) , entonces si pins se declaró como pins[5] , i será 1 , 2 3 , 4 y 5 . Suponiendo que length(pins) == length(pinValues) esto es un problema en sí mismo, ¡porque pinValues[5] ni siquiera existiría!

pinValues[5] solo crea pinValues[0] a pinValues[4] (sí, sé que es raro, estás declarando 5 elementos pero, dado que C tiene un índice de 0, son 0 , 1 , 2 , 3 y 4 ), por lo que i no debería NUNCA llegar a 5 o estará fuera de los límites, lo que es un comportamiento indefinido (y bien podría ser la fuente de sus problemas) porque estás escribiendo en la ubicación de memoria incorrecta.

La forma correcta de hacer esto es pasar de 0 a i < sizeof(pins) / sizeof(pins[0]) (observe que estricto es menos que el operador < ) que varía de 0 a length(pins) - 1 y luego solo String pinNumber = String(i + 1); . De esa manera, 1H cambiará el valor de pinValues[0] , asignando sus mensajes seriales indexados 1 a arreglos C indexados 0.

No es necesario bucear

No estoy seguro de por qué estás haciendo un bucle sobre pins . Estás haciendo un trabajo innecesario y probablemente acapare la unidad de usuario (especialmente porque, como señala Dave Tweed en la otra respuesta, estás usando funciones caras como String y comparación de cadenas con == ).

message tiene una sola instancia, por ejemplo, 1H\n , por lo que no se necesita un bucle. char pinNumber = message[0] - '0'; almacenará el valor entero del primer carácter en pinNumber , con el que podrá indexar la matriz.

¿Cómo funciona eso?

• message[0] sería un tipo char (por ejemplo, '1' )
• '0' también es un char , que corresponde al valor ASCII de 0 (48 en decimal).
• Si message[0] contiene el char '0' , entonces el resultado es '0' - '0' == 48 - 48 == 0
• Como los números son contiguos y aumentan en el conjunto ASCII , el resultado de la resta es el número real como un entero de un solo byte.
• '1' - '0' == 49 - 48 == 1 y sigue y sigue.

También es posible que desee rechazar entradas falsas:

if (pinNumber >= sizeof(pins) / sizeof(pins[0]))
  return;

Trabajo más falso

En cada iteración loop() haces esto:

// Write to pins        
for (int i = 1; i <= sizeof(pins) / sizeof(pins[0]); i++) {
  digitalWrite(pins[i], pinValues[i]);
}

Que tiene el mismo problema con los fuera de los límites que antes.

También hace un trabajo innecesario, ya que estás escribiendo TODOS los valores de pin, ya sea que hayan cambiado o no. ¿Por qué no digitalWrite(pins[pinNumber], HIGH or LOW); directamente en setPinValues y evita este bucle? Incluso podría deshacerse de la matriz pinValues si realmente no necesita almacenarlos (o puede conservarlo si lo necesita por alguna razón).

Mi setPinValues alternativo

void setPinValue(char pin, char value) {
  char pinNumber = pin - '0';  // Get the integer value of the ASCII char

  if (pinNumber >= sizeof(pins) / sizeof(pins[0]))  // Reject out-of-bounds input
    return;

  switch (value) {
    case 'H':
      pinValues[pinNumber] = HIGH;  // Not necessary if you don't want to store the pin values
      digitalWrite(pins[pinNumber], HIGH);
      break;
    case 'L':
      pinValues[pinNumber] = LOW;  // Not necessary if you don't want to store the pin values
      digitalWrite(pins[pinNumber], LOW);
  }
}

Y luego simplemente llámalo desde loop() como setPinValue(message[0], message[1]);

Hazme saber si esto resuelve tu problema.

Es un problema de rendimiento. La primera versión de setPinValues() realiza muchas llamadas a String() cada vez que se llama, y esta es una función no trivial. Esto hace que setPinValues() demore mucho más tiempo de lo que cree que termine, por lo que no es muy sorprendente que el Arduino finalmente no pueda mantenerse al día con los mensajes entrantes a 57600 bps.

En la segunda versión de setPinValues() , los argumentos para las llamadas String() son constantes, por lo que se evalúan en el momento de la compilación. Esta versión se ejecuta mucho más rápido, y es capaz de mantenerse a 57600.