Piensas en términos de crear un símbolo basado en un paquete y eso lleva a cierta confusión entre el modelo de sub-circuito de especias que también estás viendo.
En cambio, el modelo de especia que muestres está realmente diseñado para un símbolo más normal para tu esquema.
En su lugar, copia este archivo:
Version 4
SymbolType CELL
LINE Normal -32 32 32 64
LINE Normal -32 96 32 64
LINE Normal -32 32 -32 96
LINE Normal -28 48 -20 48
LINE Normal -28 80 -20 80
LINE Normal -24 84 -24 76
LINE Normal 0 32 0 48
LINE Normal 0 96 0 80
LINE Normal 4 44 12 44
LINE Normal 8 40 8 48
LINE Normal 4 84 12 84
WINDOW 0 16 32 Left 0
WINDOW 38 44 50 Left 0
SYMATTR SpiceModel LM358
SYMATTR Prefix X
SYMATTR Description National LM385
SYMATTR ModelFile LM358.MOD
PIN -32 80 NONE 0
PINATTR PinName In+
PINATTR SpiceOrder 1
PIN -32 48 NONE 0
PINATTR PinName In-
PINATTR SpiceOrder 2
PIN 0 32 NONE 0
PINATTR PinName V+
PINATTR SpiceOrder 3
PIN 0 96 NONE 0
PINATTR PinName V-
PINATTR SpiceOrder 4
PIN 32 64 NONE 0
PINATTR PinName OUT
PINATTR SpiceOrder 5
Y guárdelo como un archivo llamado LM358.ASY en algún directorio que pueda usar fácilmente. Si lo desea, vaya al directorio de instalación de LTspice, busque el subdirectorio "lib" allí, luego mire dentro y busque el subdirectorio "sym". Coloque el archivo anterior allí, si no puede colocarlo en otro lugar que sea conveniente.
Sin embargo, normalmente creo mi propio directorio de símbolos y lo coloco allí. A continuación, se puede acceder a este, accediendo primero a la selección de Herramientas / Panel de control y luego seleccionando la pestaña "Sym. & Lib. Search Paths" y agregando su propio directorio personal en el cuadro Path de búsqueda de símbolos.
Mientras esté aquí, también puede agregar un directorio propio para los modelos de simulación de Spice en ese cuadro. Guardo mis archivos de modelo en un directorio y mis archivos de símbolos en un segundo. Pero también puedes usar un directorio para ambos. No importa LTspice solo necesita ser informado de las cosas, de cualquier manera.
Luego, reinicie el programa después de guardar. Luego, cuando presiona F2, puede ver en la parte superior que hay una entrada de "Directorio principal" allí y encontrará su propio directorio personal en la lista. Selecciona eso, luego selecciona LM358 desde allí.
Cualquiera de las dos formas funciona.
Sin embargo. Como mencioné anteriormente, TAMBIÉN necesitará un archivo LM358.MOD y debe colocarse en otro directorio (o en el mismo directorio). Si observa la definición de símbolo incluida anteriormente, verá una línea que dice:
SYMATTR ModelFile LM358.MOD
Ahí es donde el símbolo apunta al archivo modelo. Por lo tanto, debe usar ese nombre o, si no, cambiar la descripción del símbolo anterior para usar el nombre que desee usar.
Luego debes almacenar tu modelo en un archivo de este tipo.
En mi caso, mi archivo modelo dice lo siguiente. Pero también puedes usar tu propio modelo. Pero creo que podrá ver dónde también se muestran los nodos como solo cinco nodos aquí. Al igual que el tuyo.
La clave de todo esto es que los números de nodo coinciden con los nodos de símbolo. Si lo desea, también puede usar LTspice para abrir el archivo LM358.ASY. Y luego puedes ver el símbolo allí. Pase el mouse sobre un pin y haga clic derecho sobre él. Verá el número de nodo listado allí y alguna otra información útil. Puede hacer coincidir estos (sus números) con el orden en que también se encuentran en la lista de nodos del subcircuito en el modelo a continuación.
Regrese y busque el archivo LM358.ASY que se muestra arriba y anote las entradas de "SpiceOrder" allí. Cinco de ellos, ¿verdad?
*//////////////////////////////////////////////////////////////////////
* (C) National Semiconductor, Inc.
* Models developed and under copyright by:
* National Semiconductor, Inc.
*/////////////////////////////////////////////////////////////////////
* Legal Notice: This material is intended for free software support.
* The file may be copied, and distributed; however, reselling the
* material is illegal
*////////////////////////////////////////////////////////////////////
* For ordering or technical information on these models, contact:
* National Semiconductor's Customer Response Center
* 7:00 A.M.--7:00 P.M. U.S. Central Time
* (800) 272-9959
* For Applications support, contact the Internet address:
* [email protected]
*//////////////////////////////////////////////////////////
*LM358 DUAL OPERATIONAL AMPLIFIER MACRO-MODEL
*//////////////////////////////////////////////////////////
*
* connections: non-inverting input
* | inverting input
* | | positive power supply
* | | | negative power supply
* | | | | output
* | | | | |
* | | | | |
.SUBCKT LM358 1 2 99 50 28
*
*Features:
*Eliminates need for dual supplies
*Large DC voltage gain = 100dB
*High bandwidth = 1MHz
*Low input offset voltage = 2mV
*Wide supply range = +-1.5V to +-16V
*
*NOTE: Model is for single device only and simulated
* supply current is 1/2 of total device current.
* Output crossover distortion with dual supplies
* is not modeled.
*
****************INPUT STAGE**************
*
IOS 2 1 5N
*^Input offset current
R1 1 3 500K
R2 3 2 500K
I1 99 4 100U
R3 5 50 517
R4 6 50 517
Q1 5 2 4 QX
Q2 6 7 4 QX
*Fp2=1.2 MHz
C4 5 6 128.27P
*
***********COMMON MODE EFFECT***********
*
I2 99 50 75U
*^Quiescent supply current
EOS 7 1 POLY(1) 16 49 2E-3 1
*Input offset voltage.^
R8 99 49 60K
R9 49 50 60K
*
*********OUTPUT VOLTAGE LIMITING********
V2 99 8 1.63
D1 9 8 DX
D2 10 9 DX
V3 10 50 .635
*
**************SECOND STAGE**************
*
EH 99 98 99 49 1
G1 98 9 POLY(1) 5 6 0 9.8772E-4 0 .3459
*Fp1=7.86 Hz
R5 98 9 101.2433MEG
C3 98 9 200P
*
***************POLE STAGE***************
*
*Fp=2 MHz
G3 98 15 9 49 1E-6
R12 98 15 1MEG
C5 98 15 7.9577E-14
*
*********COMMON-MODE ZERO STAGE*********
*
*Fpcm=10 KHz
G4 98 16 3 49 5.6234E-8
L2 98 17 15.9M
R13 17 16 1K
*
**************OUTPUT STAGE**************
*
F6 50 99 POLY(1) V6 300U 1
E1 99 23 99 15 1
R16 24 23 17.5
D5 26 24 DX
V6 26 22 .63V
R17 23 25 17.5
D6 25 27 DX
V7 22 27 .63V
V5 22 21 0.27V
D4 21 15 DX
V4 20 22 0.27V
D3 15 20 DX
L3 22 28 500P
RL3 22 28 100K
*
***************MODELS USED**************
*
.MODEL DX D(IS=1E-15)
.MODEL QX PNP(BF=1.111E3)
*
.ENDS
*$
