Tengo que diseñar un regulador de ángulo de fase con un triac. Para esto, he leído ¿Cómo conduzco un TRIAC? ¿De un microcontrolador (para bajos voltajes)?
Este foro realmente me da una buena solución ... pero antes de eso, quiero simular este circuito en LTspice o multisim o cualquier otro software ...
He buscado en Google el modelo de especia de MOC3022M pero no he tenido éxito. ¿Alguien me puede dar una sugerencia?
Un gran lugar para encontrar modelos SPICE para LTSpice es el Yahoo LTSpice Group . Deberá crear una cuenta de Yahoo para unirse al grupo (es gratis). Después de eso, tendrá una gran selección de modelos de piezas y tutoriales para ayudarlo con las simulaciones de SPICE en LTSpice.
Incluso encontré un modelo para la MOC3022M en el sitio :
* OPTO TRIAC
* Helmut Sennewald 8/10/2004
* MOC3022 I_trig=5mA
* D+ D- MT2 MT1
.SUBCKT MOC3022 1 2 3 4
.PARAM Itrig=5m
.PARAM RH1=20k
.PARAM RH2=20k
.PARAM RH3=16.7k
Q2 vb1 vb1p vd1 0 PNP1
Q1 vb1p vb1 4 0 NPN1
R3 vb1 4 {RH2}
D1 1 2 DL
R1 ctrl1 4 1
C1 ctrl1 4 10µ
R2 ctrl1 vb1 {RH1}
R4 vd1 vb1p {RH3}
B1 ctrl1 4 I=-500*I(D1)*3m/Itrig
R6 vd2 vb2 {RH2}
D3 vd2 3 D1
Q3 vb2 vb2p 4 0 PNP1
Q4 vb2p vb2 vd2 0 NPN1
E1 vd2 N001 ctrl1 4 -1
R5 N001 vb2 {RH1}
R7 vb2p 4 {RH3}
D2 3 vd1 D1
R34 3 4 100MEG
.MODEL PNP1 PNP(Is=1e-15 BF=10 Cjc=10p Cje=20p Tf=0.1u Ise=1e-12)
.MODEL NPN1 NPN(Is=1e-15 BF=10 Cjc=10p Cje=20p Tf=0.1u Ise=1e-12)
.MODEL D1 D(Is=0.1u Rs=2 Cj0=50p)
.MODEL DL D(Is=1e-20 Rs=5)
.ENDS
Recuerde que es solo un modelo, por lo que es posible que desee realizar algunas pruebas alrededor de su punto de operación y comparar el rendimiento de los modelos con la hoja de datos.